{:}Double close braces are used to avoid error messages that occur because of isolated close braces in the menu screen.  To build the menu screen, command titles are interrupted by mnemonic attribute on/off characters. Thus {{ASSIGN} becomes {{{^V}AS{^Q}SIGN}.  The final "SIGN}" would generate an error message because the close brace is not paired with an opening brace.  Omitting the extra close brace would cause a harmless error message; the macro would still run correctly.  Error messages will never occur in normal circumstances, since most macros will not intentionally include statements with isolated close brackets.~
{;}This is the MPE4WP Macro Commands (A-L) macro, which is assigned to CTRL-{{ on the MPE4WP keyboard.  Pressing CTRL-{{ brings a help screen.  Press the two-key mnemonic to insert the Macro Command with tildes.  After you have memorized the mnemonics, use Expand (CTRL-X) to eliminate the help screens.
Copyright 1991 Michael H. Shacter~

{IF}{STATE}&512~
	{Reveal Codes}
	{ASSIGN}rc~1~
{END IF}
{ON CANCEL}{GO}end~~
{ON ERROR}{GO}end~~
{CHAR}1st~{Del to EOP}
{^P}{2}{2}ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
{^P}{2}{3}³  {{;}{^V}c{^Q}o{^V}m{^Q}ment{~}                             {{{^V}E{^Q}ND {^V}F{^Q}OR}}                        ³
{^P}{2}{4}³  {{{^V}AS{^Q}SIGN}}var{~}expr{~}                       {{{^V}E{^Q}ND {^V}I{^Q}F}}                         ³
{^P}{2}{5}³  {{{^V}BE{^Q}LL}}                                  {{{^V}E{^Q}ND {^V}W{^Q}HILE}}                      ³
{^P}{2}{6}³  {{{^V}B{^Q}lock {^V}A{^Q}ppend}}                          {{{^V}FO{^Q}R}}var{~}start{~}stop{~}step{~}        ³
{^P}{2}{7}³  {{{^V}B{^Q}lock {^V}C{^Q}opy}}                            {{{^V}F{^Q}OR {^V}E{^Q}ACH}}var{~}expr1{~}...exprN{~}{~}   ³
{^P}{2}{8}³  {{{^V}B{^Q}lock {^V}M{^Q}ove}}                            {{{^V}GO{^Q}}}label{~}                       ³
{^P}{2}{9}³  {{{^V}BR{^Q}EAK}}                                 {{{^V}I{^Q}F {^V}E{^Q}XISTS}}var{~}                  ³
{^P}{2}{10}³  {{{^V}CA{^Q}LL}}label{~}                            {{{^V}IF{^Q}}}expr{~}                        ³
{^P}{2}{11}³  {{{^V}C{^Q}ANCEL O{^V}F{^Q}F}}                            {{{^V}IN{^Q}PUT}}message{~}                  ³
{^P}{2}{12}³  {{{^V}C{^Q}ANCEL {^V}O{^Q}N}}                             {{{^V}I{^Q}tem {^V}D{^Q}own}}                      ³
{^P}{2}{13}³  {{{^V}C{^Q}A{^V}S{^Q}E}}expr{~}cs1{~}lb1{~}...{~}                 {{{^V}I{^Q}tem {^V}L{^Q}eft}}                      ³
{^P}{2}{14}³  {{{^V}C{^Q}ASE {^V}C{^Q}ALL}}expr{~}cs1{~}lb1{~}...{~}            {{{^V}I{^Q}tem {^V}R{^Q}ight}}                     ³
{^P}{2}{15}³  {{{^V}C{^Q}HAI{^V}N{^Q}}}macroname{~}                       {{{^V}I{^Q}tem {^V}U{^Q}p}}                        ³
{^P}{2}{16}³  {{{^V}CH{^Q}AR}}var{~}message{~}                      {{{^V}K{^Q}TO{^V}N{^Q}}}key{~}                       ³
{^P}{2}{17}³  {{{^V}D{^Q}ISPLAY O{^V}F{^Q}F}}                           {{{^V}LA{^Q}BEL}}label{~}                    ³
{^P}{2}{18}³  {{{^V}D{^Q}ISPLAY {^V}O{^Q}N}}                            {{{^V}LE{^Q}N}}var{~}                        ³
{^P}{2}{19}³  {{{^V}EL{^Q}SE}}                                  {{{^V}LO{^Q}OK}}var{~}                       ³
{^P}{2}{20}ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;
{^P}{0}{24}{^R}Press two-key mnemonic to insert Macro Command{^S}~
{CHAR}2nd~~

		{:}convertúinputútoúupperúcase~

{ASSIGN}key~{VARIABLE}1st~~
{CALL}upper~
{ASSIGN}1st~{VARIABLE}key~~

{ASSIGN}key~{VARIABLE}2nd~~
{CALL}upper~
{ASSIGN}2nd~{VARIABLE}key~~

{ASSIGN}code~{VARIABLE}1st~{VARIABLE}2nd~~

{CALL}{VARIABLE}code~~
{GO}end~

{LABEL}CM~
{{;}{~}{left}
{RETURN}

{LABEL}AS~
{{ASSIGN}{~}{~}{left}{left}
{RETURN}

{LABEL}BE~
{{BELL}
{RETURN}

{LABEL}BA~
{{Block Append}
{RETURN}

{LABEL}BC~
{{Block Copy}
{RETURN}

{LABEL}BM~
{{Block Move}
{RETURN}

{LABEL}BR~
{{BREAK}
{RETURN}

{LABEL}CA~
{{CALL}{~}{Left}
{RETURN}

{LABEL}CF~
{{CANCEL OFF}
{RETURN}

{LABEL}CO~
{{CANCEL ON}
{RETURN}

{LABEL}CS~
{{CASE}{~}{Enter}
{~}{~}{Enter}
{~}{Left}{Left}{Left}{Left}{Left}{Left}
{RETURN}

{LABEL}CC~
{{CASE CALL}{~}{Enter}
{~}{~}{Enter}
{~}{Left}{Left}{Left}{Left}{Left}{Left}
{RETURN}

{LABEL}CN~
{{CHAIN}{~}{Left}
{RETURN}

{LABEL}CH~
{{CHAR}{~}{~}{Left}{Left}
{RETURN}

{LABEL}DF~
{{DISPLAY OFF}
{RETURN}

{LABEL}DO~
{{DISPLAY ON}
{RETURN}

{LABEL}EL~
{{ELSE}
{RETURN}

{LABEL}EF~
{{END FOR}
{RETURN}


{LABEL}EI~
{{END IF}
{RETURN}

{LABEL}EW~
{{END WHILE}
{RETURN}

{LABEL}FO~
{{FOR}{~}{~}{~}{~}{Enter}
{{END FOR}{Up}{End}{Left}{Left}{Left}{Left}
{RETURN}

{LABEL}FE~
{{FOR EACH}{~}{~}{~}{~}{Enter}
{{END FOR}{Up}{End}{Left}{Left}{Left}{Left}
{RETURN}

{LABEL}GO~
{{GO}{~}{Left}
{RETURN}

{LABEL}IE~
{{IF EXISTS}{~}{Left}
{RETURN}

{LABEL}IF~
{{IF}{~}{Enter}
{{END IF}{Up}{End}{Left}
{RETURN}

{LABEL}IN~
{{INPUT}{~}{Left}
{RETURN}

{LABEL}ID~
{{Item Down}
{RETURN}

{LABEL}IL~
{{Item Left}
{RETURN}

{LABEL}IR~
{{Item Right}
{RETURN}

{LABEL}IU~
{{Item Up}
{RETURN}

{LABEL}KN~
{{KTON}{~}{Left}
{RETURN}

{LABEL}LA~
{{LABEL}{~}{Left}
{RETURN}

{LABEL}LE~
{{LEN}{~}{Left}
{RETURN}

{LABEL}LO~
{{LOOK}{~}{Left}
{RETURN}

{LABEL}upper~
{ASSIGN}key#~{KTON}{VARIABLE}key~~~
{IF}{VARIABLE}key#~>96&{VARIABLE}key#~<123~
	{ASSIGN}key#~{VARIABLE}key#~-32~
	{ASSIGN}key~{NTOK}{VARIABLE}key#~~~
{END IF}
{RETURN}

{LABEL}end~
{Screen}{Screen}
{IF}{VARIABLE}rc~=1~
	{Reveal Codes}
	{ASSIGN}rc~0~
{END IF}
{QUIT}